Nothing is random, everything has a meaning.

Nothing is random.

Everything has a meaning.

The scene fits in under 100 lines of code (with comments! :)), so I decided to publish it here.


/**
* Simple POV-Ray scene with reflective pillars
*
* @author Vit 'tasuki' Brunner
* @license GNU GPL, http://www.gnu.org/copyleft/gpl.html
* @version 2.7, 2008-11-05
*/

// dark and reflective texture
#declare ShinyDark =
texture {
pigment { rgb 0 }
finish {
ambient 0
// reflection .3 // dark version
reflection .6 // light version
specular 3
}
}

// create a pillar of specified height
// kind of hackish, but I can't find a better way
#macro pillar(xx, yy, height)
#declare counter = height * 2;

#while (counter > -1)
superellipsoid {
<.3, .3>
texture { ShinyDark }
translate y * counter * .5
translate x * xx * 2.2
translate z * yy * 2.2
}

#declare counter = counter - 1;
#end
#end

// just some random (random, really?) pillars
pillar(-3, 3, 2)
pillar(-1, 3, 4)
pillar( 0, 3, 3)
pillar( 2, 3, 0)
pillar( 3, 3, 2)
pillar( 0, 2, 2)
pillar( 1, 2, 1)
pillar(-1, 1, 3)
pillar(-1, 0, 2)
pillar( 0, 0, 1)
pillar( 2, 0, 3)
pillar(-2,-1, 2)
pillar(-1,-1, 3)
pillar( 1,-1, 0)
pillar( 3,-1, 2)
pillar(-1,-2, 1)
pillar( 0,-2, 2)
pillar( 2,-2, 1)
pillar( 3,-2, 0)
// there's no such thing as random...

// the sphere everything is wrapped in
sphere {
<0, 100, 0>, 100
hollow
pigment { rgb 1 }
finish {
ambient .6
reflection .05
}
}

// get light quality from clock (+K in params)
#declare qualight = clock;

// back right less bright white light
light_source {
<30, 25, 40> rgb .5
area_light <0, 10, 0>, <0, 0, 10>, qualight, qualight
adaptive 1 jitter circular orient
}

// front right white light
light_source {
<30, 20, -30> rgb .7
area_light <0, 10, 0>, <0, 0, 10>, qualight, qualight
adaptive 1 jitter circular orient
}

// front left blue light
light_source {
<-15, 25, -15> rgb <.3, .7, .9>
area_light <0, 20, 0>, <0, 0, 20>, qualight, qualight
adaptive 1 jitter circular orient
}

camera {
location <7, 9, -14>
look_at <2, 1, 0>
}

To render the picture, you should run something like:


povray +Ifilename.pov +FN +W1024 +H768 +Q9 +QR +A0.5 +AM2 +K11

Well, that’s it. Hope you enjoyed ^^

Oh, you actually want to see the picture? Please check it out on deviantart.

And remember: Nothing is random, everything has a meaning…

One thought on “Nothing is random, everything has a meaning.

Comments are closed.